xml de link sorunu

[haydarxxx]

slmlar
arkadaşlar haberBaslik.swf adlı dosyam xlm dosyadan vari çekiyor. kodları şu şekilde gidiyor

Kod: Tümünü seç

<?xml version="1.0" encoding="windows-1254"?>

<haberler>

  <haber>
    <baslik> 10/04/2009 Haberler1</baslik>
    <ozet>delphiturkiye forum adresine gidecek gidecek</ozet>
    <tarih>12/03/2011</tarih>
    <resimYolu>Haberresimleri/2.jpg</resimYolu>
  <link>http://www.delphiturkiye.com/forum/ </link>

  </haber>

kodu bu şekilde ama <link> kodu çalışmıyor.Birde bu dosyanın haberBaslik.fla dosyası var fladan mı ayar yapmam lazım.net de xml link vermeleri aradım ama buradaki türkçe kod sistemine hiç biri uymuyor.Bu konuda ayrıntılı bir bilgi vercek olursa sevinirim.Teşekkürler

[mkysoft]

xml'in bir önemi yok. herşey fla içinde. swf içinde yazılan kodlar sizin yazdığınızdan farklı bir xml bekliyor olabilir. actionscript kodlarını kontrol etmelisiniz fla dosyasından. ayrıca haberler tag'ını kapatmamışsınız, alakası var mıdır bilmem.

[haydarxxx]

hocam xml de kısa bir kod parçasını vermiştim haber tag ında bir sorun yok .fla action kodunada baktım ben bir hata göremedim bir incelermisiniz

Kod: Tümünü seç

import fl.transitions.Tween;
import fl.transitions.easing.*;

stop();
//kayıt sayısını saymak için
var sayac:Number=0;
//Toplam haber sayısı
var ToplamHaberSayisi:int=0;
//XML veriyi yükleyen
var xmlLoader:URLLoader;
var haberXML:XML;

//genel bir obje belirleyelim
var obj:Object=new Object();

//-------------------------------------------xml yükleyelim

xmlLoader = new URLLoader();
xmlLoader.addEventListener(Event.COMPLETE, LoadXML);
xmlLoader.load(new URLRequest("haberler.xml"));



function LoadXML(e:Event):void {
	haberXML=new XML(e.target.data);
	ParseBooks(haberXML);
}
function ParseBooks(haberXML:XML) {
	//bu satırda haber düğümün altındaki başlıkları değişkene alır böylece toplam sayıyı ala bilriz , ardında diyer veriere ulaşmak 
	//için baslik yerine link resimyolu gibi düğümleri yazarız
	var Haberler:XMLList=haberXML.haber.baslik;
	ToplamHaberSayisi=Haberler.length();

	//haber başlıkları arasındaki boşluk
	var BasliklarArasindakiBosluk:int=25;
	for (var sayac:Number=0; sayac<Haberler.length(); sayac++) {
		//haber sayısı kadar başlık oluştur
		var baslik_RT_mc:Baslik=new Baslik();
		baslik_RT_mc.x=400;
		baslik_RT_mc.y=(sayac * BasliklarArasindakiBosluk)+8;//hepsi 5px aşağıdan başlasın
		baslik_RT_mc.baslik_txt.text=haberXML.haber.baslik[sayac].substr(0,43)+"...";
		baslik_RT_mc.addEventListener(MouseEvent.MOUSE_OVER,ozetiGoster);
		baslik_RT_mc.addEventListener(MouseEvent.CLICK,adresiCagir);
		baslik_RT_mc.buttonMode=true;
		baslik_RT_mc.name="baslik_"+sayac;
		baslik_RT_mc.sayac=sayac;//daha sonra kullanmak için
		addChild(baslik_RT_mc);

	}
	myTimer.start();
	//ilk yüklemede 0 kayıdı göster
	haberiGoster(0);
}

//otomatik 5sn de bir başka habere kec
var myTimer:Timer=new Timer(8000,1000);
myTimer.addEventListener("timer", otomatikSiradakiniGoster);

function otomatikSiradakiniGoster(event:TimerEvent) {

	var sira:Number=myTimer.currentCount-1;
 	haberiGoster(sira);
	if(sira>=ToplamHaberSayisi-1)
	{
		myTimer.reset();
		myTimer.start();
	}
}


function haberiGoster(sira:Number)
{
	resimAltiBaslik_mc.resimAltiBaslik_txt.text=haberXML.haber.baslik[sira].substr(0,100)+"...";
	ozet_mc.ozet_txt.text=haberXML.haber.ozet[sira].substr(0,150)+"...";
	if (haberXML.haber.resimYolu[sira]!="") {
		resmiYukle(haberXML.haber.resimYolu[sira]);
	} else {
		resmiYukle("bilesenler/bil_onsayfa/bos.png");
	}
	//işşaretçiyi konumlandır
	var btn:Object=new Object();
	btn=getChildByName("baslik_"+sira);
	//trace(btn+"--------------");
	var myTween:Tween = new Tween(isaretci_mc, "y",Elastic.easeOut,isaretci_mc.y,btn.y+10,1,true);
	var myTween_:Tween = new Tween(resim_mc, "y",Elastic.easeOut,20,5,1,true);
	//isaretci_mc.y=obj.y+10;
}

function adresiCagir(evt:MouseEvent) {

	var url:String = haberXML.haber.link[obj.sayac];
	var request:URLRequest = new URLRequest(url);
	try {
		navigateToURL(request, '_self');// second argument is target
	} catch (e:Error) {
		trace("Error occurred!");
	}

}
function ozetiGoster(evt:MouseEvent) {

	obj=evt.target;
 	haberiGoster(obj.sayac);
}
function resmiYukle(resminYolu:String) {
	//yüklemeden önce  resim_mc içini temizle
	var cocuksayisi:Number=resim_mc.numChildren;
	while (cocuksayisi--) {
		resim_mc.removeChildAt(cocuksayisi);
	}
	var pictLdr:Loader = new Loader();
	var pictURL:String = resminYolu;
	var pictURLReq:URLRequest = new URLRequest(pictURL);
	pictLdr.load(pictURLReq);
	pictLdr.contentLoaderInfo.addEventListener( Event.INIT,loaded);
	pictLdr.contentLoaderInfo.addEventListener( Event.COMPLETE,yuklendi);
	onyukleme_mc.visible=true;
	onyukleme_mc.gotoAndPlay(1);
	function loaded(event:Event):void {
		var targetLoader:Loader = Loader(event.target.loader);
		targetLoader.x=6;
		targetLoader.y=6;
		targetLoader.width = 373;
		targetLoader.height=236;
		resim_mc.addChild(targetLoader);
		//trace(targetLoader.loaderInfo.bytesLoaded);
	}
	function yuklendi(event:Event):void {
		onyukleme_mc.visible=false;
	}
}


///işaretçiyi ekle
var isaretci_mc:Isaretci=new Isaretci();
isaretci_mc.x=392;
isaretci_mc.name="isaretci_mc";
addChild(isaretci_mc);
//resim_mc ye tıklanınca adres çağırsın
resim_mc.addEventListener(MouseEvent.CLICK,adresiCagir);
resim_mc.buttonMode=true;
ozet_mc.addEventListener(MouseEvent.CLICK,adresiCagir);
ozet_mc.ozet_txt.mouseEnabled=false;
ozet_mc.buttonMode=true;