Query Editör fields'e Run-Time da alan adlarını eklemek?

[kahraman1285]

Merhaba

Bir query yada Table nesnesinin üzerini çift tıkladığımızda o nesnenin Editör Fields kısmı açılır ve sağ tıklayarak Add all fields komutuyla bağlı olduğu table'ın alan adları listeye eklenir.

*Ben bu işlemi Run-Time da kod yazarak nasıl yapabilirim?

[img][img]http://img254.imageshack.us/img254/8860 ... e10ri3.jpg[/img][/img]

[sadettinpolat]

run-time da bu islemi yapabileceginiz bi kisayolun oldugunu sanmiyorum. cunku bu islem sonucunda kaynak koda yeni yeni siniflar eklenir.

run-time da tbu tip bir islem yapmak icin fieldin tipini belirleyip uygun bir sinif secerek ilgili atamalari yapmaniz gerekir.

formun dfm dosyasinda ve pas dosyasinda bunlari gorebilirsiniz.

dfm dosyasinda

Kod: Tümünü seç

    object Table1Country: TStringField
      FieldName = 'Country'
    end

pas dosyasinda

Kod: Tümünü seç

    Table1Country: TStringField;

[delphiibo]

Eklenebiliyor. Aşağıdaki kodu kullan.

Kullanımı :

AddAllFields(DatasetComponentAdın);

Bu Kadar. Çok aranan bir kod aslında. bende yabancı bir sitede denk geldim.

Kod: Tümünü seç

procedure AddAllFields(DataSet: TDataset);
var
   FieldsList: TStringList;
   FieldName: WideString;
   Field: TField;
   WasActive: boolean;
   FieldDef: TFieldDef;
   i: Integer;
   FieldNameBas : string;
begin
   WasActive := DataSet.Active;
   FieldNameBas := DataSet.Name;
   if WasActive then
      DataSet.Active := False;
   try
      FieldsList := TStringList.Create;
      try
         DataSet.FieldDefs.Update;

         for i := 0 to DataSet.FieldDefList.Count - 1 do
            with DataSet.FieldDefList[i] do
               if (FieldClass <> nil) and not(faHiddenCol in Attributes) then
               begin
                  FieldName := DataSet.FieldDefList.Strings[i];
                  Field := DataSet.FindField(FieldName);
                  if (Field = nil) or (Field.Owner <> DataSet.Owner) then
                     FieldsList.Add(FieldName);
            end;

         for i := 0 to FieldsList.Count - 1 do
         begin
            FieldName := FieldsList[i];
            FieldDef := DataSet.FieldDefList.FieldByName(FieldName);
            Field := FieldDef.CreateField(DataSet.Owner, nil, FieldName, False);
            try
               Field.name := FieldNameBas + FieldName + IntToStr(random(MaxInt)); // make the name unique
            except
               Field.Free;
               raise ;
            end;
         end;
      finally
         FieldsList.Free;
      end;
   finally
      if WasActive then
         DataSet.Active := true;
   end;
end;

[burakb44]

Eklenebiliyor. Aşağıdaki kodu kullan.

Kullanımı :

AddAllFields(DatasetComponentAdın);

Bu Kadar. Çok aranan bir kod aslında. bende yabancı bir sitede denk geldim.

Kod: Tümünü seç

procedure AddAllFields(DataSet: TDataset);
var
   FieldsList: TStringList;
   FieldName: WideString;
   Field: TField;
   WasActive: boolean;
   FieldDef: TFieldDef;
   i: Integer;
   FieldNameBas : string;
begin
   WasActive := DataSet.Active;
   FieldNameBas := DataSet.Name;
   if WasActive then
      DataSet.Active := False;
   try
      FieldsList := TStringList.Create;
      try
         DataSet.FieldDefs.Update;

         for i := 0 to DataSet.FieldDefList.Count - 1 do
            with DataSet.FieldDefList[i] do
               if (FieldClass <> nil) and not(faHiddenCol in Attributes) then
               begin
                  FieldName := DataSet.FieldDefList.Strings[i];
                  Field := DataSet.FindField(FieldName);
                  if (Field = nil) or (Field.Owner <> DataSet.Owner) then
                     FieldsList.Add(FieldName);
            end;

         for i := 0 to FieldsList.Count - 1 do
         begin
            FieldName := FieldsList[i];
            FieldDef := DataSet.FieldDefList.FieldByName(FieldName);
            Field := FieldDef.CreateField(DataSet.Owner, nil, FieldName, False);
            try
               Field.name := FieldNameBas + FieldName + IntToStr(random(MaxInt)); // make the name unique
            except
               Field.Free;
               raise ;
            end;
         end;
      finally
         FieldsList.Free;
      end;
   finally
      if WasActive then
         DataSet.Active := true;
   end;
end;

hay allah razı olsun senden çok güzel bi kod gerçekten denedim sorunsuz çalışıyor. teşekkürler.

[erdemdemirel]

Hay Allah razı olsun yaa...

[firatdesign]

bu kodu forma ekledim fakat ben alan adlarını nasıl kullanabilirim adotable1Miktar.value şeklindeki gibi nasıl kullanıcam yardım lütfen